Гайдар Магдануров
Переход на VB .NET, статья №2
Upgrade Wizard или автоматизированная миграция кода

Статья предоставлена журналом CODE. Ссылка на VBStreets и CODE обязательна.

Введение

Перед вами вторая статья цикла, посвященного переходу на платформу .NET. В ней рассматриваются основные принципы работы с утилитой для автоматизированной миграции кода – мастером Upgrade Wizard, входящим в базовую поставку Microsoft Visual Studio .NET. Прежде, чем преступать к осмысленному изменению кода вашего проекта, настоятельно рекомендуется «пропустить» его через Upgrade Wizard, в дальнейшем мы сможем разобрать случаи, в которых лучшим решением будет изменение кода в Visual Basic 6.0, но не имея общей картины предстоящей работы сделать это практически невозможно.
Основная концепция Upgrade Wizard – как можно точнее сохранить ваш код, внести как можно меньше изменений, изменяя код лишь там, где это действительно необходимо. При этом будут сохранены все названия переменных, пользовательских классов, функций, методов и свойств¹.
Исходный код к статье доступен на сайте.

Знакомьтесь – мастер обновления кода Upgrade Wizard

Прежде всего, разберемся – что, собственно, может сделать мастер Upgrade Wizard? Мастер предназначен для выполнения следующей работы:

• Создание проекта, эквивалентного по структуре и содержанию, обновляемому проекту. Основная цель – получить работоспособный «скелет», несущий основные элементы функциональности обновляемого проекта.
• Преобразование всех свойств и атрибутов проекта к аналогичным в VB .NET, если это возможно, либо уведомить разработчика о необходимости реализации данных свойств другим методом, совместимым с .NET.
• Преобразование форм VB6.0 в эквивалентные по внешнему виду и содержанию элементы Windows Forms. При этом происходит замена всех существующих на форме стандартных контролов на аналоги .NET.
• Преобразование ссылок на third-party ActiveX контролы.
• Преобразование кода. При этом устаревший синтаксис, не поддерживаемый VB .NET будет заменен на соответствующий новый.
• Замену типов переменных в соответствии с типами VB .NET. В Таблице 1 приведены типы данных в .NET. В соответствии с этой таблицей сопоставляются по размеру типы VB 6.0 и VB .NET.

Таблица 1

Не все так радужно, как может показаться на первый взгляд. В соответствии с тем, что Visual Basic .NET не поддерживает некоторых устаревших технологий, либо предоставляет несколько иную их поддержку, Upgrade Wizard для нескольких типов проектов не может провести миграцию кода в полном объеме. Проблемы возникают при попытке обновления проектов следующих типов:

• ActiveX EXE
• ActiveX Document EXE / ActiveX Document DLL
• Приложений использующих OLE
• Приложений использующих Drag And Drop
• Приложений использующих Dynamic Data Exchange (DDE)
• Приложения использующие графические контролы (Shape)
• Расширений VB IDE
• DHTML Приложений

Начинаем работу с Upgrade Wizard

Пример всегда воздействует сильнее, чем проповедь.
Сэмюэль Джонсон

Для большей наглядности, создадим небольшое приложение на Visual Basic 6.0, над которым в дальнейшем и будем работать с помощью Upgrade Wizard. Пример будет достаточно прост и предназначен лишь для того, чтобы показать возможность Upgrade Wizard.
Исходный код приведен ниже:

'frmParent

Private Sub cColor_Click()
frmColor.BackColor = CLng(cColor.Text)
End Sub

Private Sub cmdShow_Click()
ShowForm CLng(cColor.Text), txtCaption.Text
End Sub

Private Sub Form_Load()
cColor.Clear
cColor.AddItem CStr(vbRed)
cColor.AddItem CStr(vbGreen)
cColor.AddItem CStr(vbBlue)
cColor.AddItem CStr(vbYellow)
cColor.AddItem CStr(vbMagenta)
cColor.AddItem CStr(vbBlack)
cColor.ListIndex = 0
End Sub

Private Sub Form_Unload(Cancel As Integer)
End
End Sub

'modMain

Public Sub ShowForm(mColor As Long, mCaption As String)
Dim obj As frmChild
Set obj = New frmChild
obj.BackColor = mColor
obj.Caption = mCaption
obj.Show
End Sub

Рис. 1.

Рис. 2.

Таблица 2

Рассмотрим наш конкретный пример. Благодаря его простоте, мы не обнаружим в нем трудно исправимых ошибок, поэтому перейдем непосредственно к ознакомлению со сгенерированным кодом и исправлению ошибок. Если вы обратили внимание – проект выполняется без ошибок, но, если мы не хотим иметь проблем в будущем, лучше сразу же разобраться со всеми предупреждениями Upgrade Wizard.
Для начала, воспользовавшись меню или комбинацией Ctrl+Alt+K, отобразим список задач (Task List), в котором приведены все, заботливо оставленные Upgrade Wizard замечания. После этого дважды щелкнув по frmParent в списке файлов проекта, мы увидим замечания, относящиеся к этому файлу. Неправда ли, удобно? Но мы не пойдем этим путем. Открыв файл в редакторе исходного кода, мы начнем исследовать код с самого начала.
Прежде всего, мы встречаемся с настройками компилятора. По умолчанию Upgrade Wizard устанавливает их именно таким образом, чтобы избежать излишних сообщений связанных с автоматическим преобразованием типов, которые так часто встречается в VB6.0. Раз уж мы собрались делать все как надо, то необходимо установить Option Strict On.
Далее весьма интересным моментом является:

Public Shared Property DefInstance() As frmParent
		Get
			If m_vb6FormDefInstance Is Nothing OrElse m_vb6FormDefInstance.IsDisposed Then
				m_InitializingDefInstance = True
				m_vb6FormDefInstance = New frmParent()
				m_InitializingDefInstance = False
			End If
			DefInstance = m_vb6FormDefInstance
		End Get
		Set
			m_vb6FormDefInstance = Value
		End Set
	End Property

	'UPGRADE_WARNING: Event cColor.SelectedIndexChanged may fire when form is intialized.
	Private Sub cColor_SelectedIndexChanged(ByVal eventSender As System.Object, ByVal eventArgs _
    As System.EventArgs) Handles cColor.SelectedIndexChanged
		frmColor.BackColor = System.Drawing.ColorTranslator.FromOle(CInt(cColor.Text))
	End Sub

'UPGRADE_WARNING: Form event frmParent.Unload has a new behavior.
	Private Sub frmParent_Closed(ByVal eventSender As System.Object, ByVal eventArgs _ 
	As System.EventArgs) Handles MyBase.Closed
		End
	End Sub

Public Sub ShowForm(ByRef mColor As Integer, ByRef mCaption As String)
		Dim obj As frmChild
		obj = New frmChild
		obj.BackColor = System.Drawing.ColorTranslator.FromOle(mColor)
		obj.Text = mCaption
		obj.Show()
	End Sub

Обновление файлов проекта

Обновление проекта начинается с загрузки его в Upgrade Wizard. Соответственно, сам файл проекта с расширением .vbp является отправной точкой для мастера. Несмотря на то, что файлы проектов VB6.0 и VB.NET значительно отличаются по своему формату, но содержат ту же базовую информацию – название и версию проекта, список исходных файлов, информацию о разработчике, используемых компонентах. Помимо этого в проекте VB .NET также содержится информация о импортируемых пространствах имен и установках компилятора (по умолчанию для Debug и Release версий). В этом легко убедится, открыв файлы .vbp и .vbproj в текстовом редакторе^{A href="#7>7}.
При обновлении проекта, Upgrade Wizard, если это возможно, обновляет его до эквивалентного проекта VB .NET, в Таблице 3 приведены возможные варианты.

Таблица 3

Все атрибуты проекта, имеющие аналоги в VB .NET будут перенесены без изменений. Имя проекта будет преобразовано в имя главного пространства имен проекта .NET. Также будет перенесена информация о версии и разработчике проекта. Также будут сохранены все константы условной компиляции. Все файлы с исходным кодом проекта сохранят свои названия, Upgrade Wizard лишь изменит все расширения на .vb.
Сложнее дело обстоит с установками компилятора. Компилятора VB 6.0 и VB .NET в корне различны – если VB 6.0 создает «обычный» двоичный код, то VB .NET создает промежуточный код, поэтому настройки, имеющие смысл для двоичного кода, не имеют его для управляемого кода .NET. Все установки компилятора для проекта VB6.0 будут утеряны при обновлении. Также Upgrade Wizard игнорирует заданные параметры командной строки, используемые для отладки приложений воспринимающие команды непосредственно как параметры с командной строки. Это большой минус мастера, но легко может быть исправлен – для этого необходимо задать те же параметры в свойствах проекта VB .NET.

Обновление форм VB 6.0

VB .NET использует принципиально новую технологию по работе с формами. Этой теме будет посвящена отдельная статья цикла, здесь же будут приведены лишь основные сведения по создаваемому Upgrade Wizard коду.
Основное отличие, с которым сталкивается разработчик, состоит в том, что свойства и расположение контролов на форме VB 6.0 описывалось в заголовке .frm файла и не было доступно для непосредственного редактирования (если, конечно, особо хитрый разработчик не использовал текстовый редактор). С точки VB .NET все контролы на форме располагаются непосредственно в коде самой формы. Там же и задаются свойства. Для разработчика этот код предельно открыт и ничем не отличается от кода любой функции, задающей свойства или положения элементов форм. Открыв файл frmParent.vb вы сможете убедиться в этом лично.

...
		Me.frmColor.Name = "frmColor"
		Me.cmdShow.Cursor = System.Windows.Forms.Cursors.Default
		Me.cmdShow.RightToLeft = System.Windows.Forms.RightToLeft.No
		Me.cmdShow.TabStop = True

...

		Me.cColor.CausesValidation = True
...
		Me.txtCaption.Size = New System.Drawing.Size(181, 20)
		Me.txtCaption.Location = New System.Drawing.Point(80, 43)
...

Таблица 4

Обновление модулей и классов

Все модули и классы проекта будут автоматически обновлены до соответствующих в VB .NET, при функции, методы и свойства будут сохранены без изменений. При этом атрибуты классов будут сопоставлены следующим образом: Private будет изменен на Friend, а все остальные возможные на Public.

Обновление кода

Вот мы и дошли до момента, который больше всего интересует разработчиков – что же случится с моим кодом? Как мы могли убедиться на приведенном выше примере, несмотря на изменения, код по-прежнему можно узнать без особых усилий. В следующих статьях цикла будут рассмотрены непосредственно новый синтаксис и новые возможности языка, здесь же приведены основные изменения кода, которые происходят при миграции с использованием Upgrade Wizard.

Предопределенные функции

Прежде всего, Upgrade Wizard сохраняет синтаксис там, где это возможно. Все языковые конструкции, поддерживаемые VB 6.0 и VB .NET одновременно остаются неизменными¹⁰, для элементов языка сопоставляются эквиваленты. Например:

'VB6
a = Cos(f)
a = Sin(f)
a = Sqrt(f)

'VB .NET
a = System.Math.Cos(f)
a = System.Math.Sin(f)
a = System.Math.Sqrt(f)

Объявление переменных

Во время обновления кода, Upgrade Wizard автоматически добавляет директиву OptionExplicit On, при этом мастер автоматически добавляет декларации всех используемых переменных. Если переменные были объявлены без указания типа, например Dim SomeVar, что для VB 6.0 аналогично Dim SomeVar As Variant, то при обновлении Upgrade Wizard объявит переменную как Object: Dim SomeVar As Object.
Любой тип в .NET представляет собой объект и наследует себя от базового типа Object, который по своему использованию сравним с типом Variant в VB 6.0. Переменной типа Object может быть присвоено значение любого другого типа.
Если подобные переменные были объявлены не явно, а с использованием DefType (например DefInt или DefStr), то их объявления будут исправлены на явные именно там, где объявляется каждая конкретная переменная. Объявление с использованием DefType не поддерживаются VB .NET.

DefInt a-z

'VB6
Dim a
Dim b
Dim c

'VB.NET
Dim a As Short
Dim b As Short
Dim c As Short

Строки ограниченной длины

Объявление строковых переменных с фиксированной длиной в VB .NET является ошибкой. Для реализации подобной функциональности есть два пути – с использованием библиотеки VB6:

Dim mString As Microsoft.VisualBasic.Compatibility.VB6
mString = Microsoft.VisualBasic.Compatibility.VB6.FixedLengthsString(4)

Dim mString(4) As Char

Объявления массивов

К огромному огорчению большого числа разработчиков на VB 6.0, VB .NET не поддерживает стандартных массивов с ненулевой нижней границей. При этом нельзя задать не только отрицательную, но и положительную границу отличную от нуля. Директива OptionBase N не поддерживается компилятором VB .NET. Upgrade Wizard оставит предупреждение об отсутствии поддержки подобных массивов:

Dim a(-5 To 5) As Integer
Dim b(5 To 10) As Long

Dim mArray As System.Array
Dim lenghts(0) As Integer ‘ Длины создаваемых массивов
Dim lowerBounds(0) As Integer‘ Массив нижних границ
lenghts(0) = 10
lowerBounds(0) = -5
mArray = System.Array.CreateInstance(GetType(Integer), lenghts, lowerBounds)

Dim lengths() As Integer = {3, 5}
Dim lowerBounds() As Integer = {2, 3}
Dim myArray As Array = Array.CreateInstance(GetType(Integer), _
lengths, lowerBounds)

Объявления функций

Названия и порядок передаваемых параметров остаются теми же, но, в соответствии с требованиями VB .NET добавляются указание на то, каким образом передаются параметры функции – по ссылке (ByRef) или по значению (ByVal). Так как в VB 6.0, по умолчанию параметры передаются по ссылке, мастер, везде, где это не указано явно, добавляет ByRef. Также везде при вызовах функции в коде, мастер добавит круглые скобки (там, где они отсутствуют), согласно требованиям нового синтаксиса VB .NET.

'VB6
Private Function SayHello(msg As _
String) As Boolean
    MsgBox msg
    SayHello = True
End Function

SayHello “Hi!”

'VB.NET
Private Function SayHello(ByRef msg As String) As Boolean
		MsgBox(msg)
		SayHello = True
End Function

SayHello("Hi!")

Область видимости переменных

Одной из неприятных проблем, которые обычно не возникают при хорошем стиле программирования в VB 6.0, но встречается достаточно часто – объявление переменных внутри конструкций If…Then…Else или For…Next, при этом в VB 6.0 эти переменные видны в пределах функции, а в VB .NET только в пределах соответствующих конструкций, что вызывает ошибки при попытке компиляции подобного кода. Чтобы избежать подобных неприятностей достаточно вынести все объявления из этих конструкций.

События

VB .NET не сопоставляет события и обработчики по имени функции-обработчика, поэтому при обновления кода к объявлению каждой функции-обработчика события добавляется необходимая директива Handles, указывающая на то, обработчиком для какого события служит конкретная функция. Также, VB .NET передает всем обработчикам одинаковое количество параметров – объект, вызвавший данное событие, и объект, содержащий все аргументы этого события, таким образом, все функции-обработчики имеют идентичные объявления. Например:

Private Sub Command1_Click()
End Sub

Private Sub Form1_Load(ByVal _
eventSender As System.Object, ByVal _
eventArgs As System.EventArgs) _
Handles MyBase.Load
End Sub

Заключение

Статья заключает собой своеобразное введение в обновление проектов VB6.0 до .NET¹¹. В статье приведены основные моменты, с которыми сталкивается разработчик при использовании мастера автоматизированной миграции кода Upgrade Wizard. В следующих статьях цикла будут подробнее рассмотрены этапы обновления специфических технологий VB 6.0, обновление форм до Windows Forms, работа с ActiveX контролами и многое другое, что необходимо знать программисту, начавшему обновление проектов до VB .NET.
 

Вверх